Move files around...

- "kernel" and "repos.nix" --> "common/"
- "firmware/surface-go/ath10k" --> "surface-go/firmware/ath10k"
- Update where "kernel", "firmware/surface-go" and "repos.nix" can be found

microsoft/surface/common/kernel/default.nix

@@ -0,0 +1,16 @@
+{ lib, ... }:
+
+let
+  inherit (lib) mkOption types;
+
+in {
+  imports = [
+    ./linux-5.19.17
+    ./linux-6.0.11
+  ];
+
+  options.microsoft-surface.kernelVersion = mkOption {
+    description = "Kernel Version to use (patched for MS Surface)";
+    type = types.enum [ ];
+  };
+}

microsoft/surface/common/kernel/linux-5.19.17/default.nix

@@ -0,0 +1,37 @@
+{ config, lib, pkgs, ... }:
+
+let
+  inherit (lib) mkIf mkOption types;
+  inherit (pkgs) fetchurl;
+
+  inherit (pkgs.callPackage ../linux-package.nix { }) linuxPackage repos;
+
+  cfg = config.microsoft-surface;
+
+  version = "5.19.17";
+  extraMeta.branch = "5.19";
+  patchDir = repos.linux-surface + "/patches/${extraMeta.branch}";
+  kernelPatches = pkgs.callPackage ./patches.nix {
+    inherit (lib) kernel;
+    inherit version patchDir;
+  };
+
+  kernelPackages = linuxPackage {
+    inherit version extraMeta kernelPatches;
+    src = fetchurl {
+      url = "mirror://kernel/linux/kernel/v5.x/linux-${version}.tar.xz";
+      sha256 = "sha256-yTuzhKl60fCk8Y5ELOApEkJyL3gCPspliyI0RUHwlIk=";
+    };
+  };
+
+in {
+  options.microsoft-surface.kernelVersion = mkOption {
+    type = types.enum [ "5.19.17" ];
+  };
+
+  config = mkIf (cfg.kernelVersion == "5.19.17") {
+    boot = {
+      inherit kernelPackages;
+    };
+  };
+}

microsoft/surface/common/kernel/linux-5.19.17/patches.nix

@@ -0,0 +1,123 @@
+{ kernel,
+  patchDir,
+  version,
+}:
+
+[
+  {
+    name = "microsoft-surface-patches-linux-${version}";
+    patch = null;
+    structuredExtraConfig = with kernel; {
+      #
+      # Surface Aggregator Module
+      #
+      SURFACE_AGGREGATOR = module;
+      SURFACE_AGGREGATOR_ERROR_INJECTION = no;
+      SURFACE_AGGREGATOR_BUS = yes;
+      SURFACE_AGGREGATOR_CDEV = module;
+      SURFACE_AGGREGATOR_REGISTRY = module;
+
+      SURFACE_ACPI_NOTIFY = module;
+      SURFACE_DTX = module;
+      SURFACE_PLATFORM_PROFILE = module;
+
+      SURFACE_HID = module;
+      SURFACE_KBD = module;
+
+      BATTERY_SURFACE = module;
+      CHARGER_SURFACE = module;
+
+      #
+      # Surface laptop 1 keyboard
+      #
+      SERIAL_DEV_BUS = yes;
+      SERIAL_DEV_CTRL_TTYPORT = yes;
+
+      #
+      # Surface Hotplug
+      #
+      SURFACE_HOTPLUG = module;
+
+      #
+      # IPTS touchscreen
+      #
+      # This only enables the user interface for IPTS data.
+      # For the touchscreen to work, you need to install iptsd.
+      #
+      MISC_IPTS = module;
+
+      #
+      # Cameras: IPU3
+      #
+      VIDEO_IPU3_IMGU = module;
+      VIDEO_IPU3_CIO2 = module;
+      CIO2_BRIDGE = yes;
+      INTEL_SKL_INT3472 = module;
+
+      #
+      # Cameras: Sensor drivers
+      #
+      VIDEO_OV5693 = module;
+      VIDEO_OV8865 = module;
+
+      #
+      # ALS Sensor for Surface Book 3, Surface Laptop 3, Surface Pro 7
+      #
+      APDS9960 = module;
+
+      #
+      # Other Drivers
+      #
+      INPUT_SOC_BUTTON_ARRAY = module;
+      SURFACE_3_BUTTON = module;
+      SURFACE_3_POWER_OPREGION = module;
+      SURFACE_PRO3_BUTTON = module;
+      SURFACE_GPE = module;
+      SURFACE_BOOK1_DGPU_SWITCH = module;
+    };
+  }
+  {
+    name = "ms-surface/0001-surface3-oemb";
+    patch = patchDir + "/0001-surface3-oemb.patch";
+  }
+  {
+    name = "ms-surface/0002-mwifiex";
+    patch = patchDir + "/0002-mwifiex.patch";
+  }
+  {
+    name = "ms-surface/0003-ath10k";
+    patch = patchDir + "/0003-ath10k.patch";
+  }
+  {
+    name = "ms-surface/0004-ipts";
+    patch = patchDir + "/0004-ipts.patch";
+  }
+  {
+    name = "ms-surface/0005-surface-sam";
+    patch = patchDir + "/0005-surface-sam.patch";
+  }
+  {
+    name = "ms-surface/0006-surface-sam-over-hid";
+    patch = patchDir + "/0006-surface-sam-over-hid.patch";
+  }
+  {
+    name = "ms-surface/0007-surface-button";
+    patch = patchDir + "/0007-surface-button.patch";
+  }
+  {
+    name = "ms-surface/0008-surface-typecover";
+    patch = patchDir + "/0008-surface-typecover.patch";
+  }
+  {
+    name = "ms-surface/0009-surface-gpe";
+    patch = patchDir + "/0009-surface-gpe.patch";
+  }
+  {
+    name = "ms-surface/0010-cameras";
+    patch = patchDir + "/0010-cameras.patch";
+  }
+  {
+    name = "ms-surface/0011-amd-gpio";
+    patch = patchDir + "/0011-amd-gpio.patch";
+  }
+]

microsoft/surface/common/kernel/linux-6.0.11/default.nix

@@ -0,0 +1,38 @@
+{ config, lib, pkgs, ... }:
+
+let
+  inherit (lib) mkIf mkOption types;
+  inherit (pkgs) fetchurl;
+
+  inherit (pkgs.callPackage ../linux-package.nix { }) linuxPackage repos;
+
+  cfg = config.microsoft-surface;
+
+  version = "6.0.11";
+  extraMeta.branch = "6.0";
+  patchDir = repos.linux-surface + "/patches/${extraMeta.branch}";
+  kernelPatches = pkgs.callPackage ./patches.nix {
+    inherit (lib) kernel;
+    inherit version patchDir;
+  };
+
+  kernelPackages = linuxPackage {
+    inherit version extraMeta kernelPatches;
+    src = fetchurl {
+      url = "mirror://kernel/linux/kernel/v6.x/linux-${version}.tar.xz";
+      sha256 = "sha256-K65hMeZJceHjT/OV+lQpcRNMhXvbCykGmrhHx8mpx2I=";
+    };
+  };
+
+
+in {
+  options.microsoft-surface.kernelVersion = mkOption {
+    type = types.enum [ "6.0.11" ];
+  };
+
+  config = mkIf (cfg.kernelVersion == "6.0.11") {
+    boot = {
+      inherit kernelPackages;
+    };
+  };
+}

microsoft/surface/common/kernel/linux-package.nix

@@ -0,0 +1,22 @@
+{ lib,
+  buildLinux,
+  callPackage,
+  linuxPackagesFor,
+}:
+
+let
+  inherit (lib) recurseIntoAttrs;
+
+in {
+  repos = callPackage ../repos.nix {};
+
+  linuxPackage =
+    { version,
+      modDirVersion ? version,
+      ...
+    } @ args:
+    let
+      buildLinux' = buildLinux (args // { inherit modDirVersion; });
+      linuxPackagesFor' = linuxPackagesFor buildLinux';
+    in recurseIntoAttrs linuxPackagesFor';
+}