Move common modules into folder

framework/13-inch/common/amd.nix

@@ -0,0 +1,11 @@
+{ lib, ... }: {
+  imports = [
+    ../../../common/cpu/amd
+    ../../../common/cpu/amd/pstate.nix
+    ../../../common/gpu/amd
+  ];
+
+  # AMD has better battery life with PPD over TLP:
+  # https://community.frame.work/t/responded-amd-7040-sleep-states/38101/13
+  services.power-profiles-daemon.enable = lib.mkDefault true;
+}

framework/13-inch/common/default.nix

@@ -0,0 +1,29 @@
+{ lib, ... }: {
+  imports = [
+    ../../common/pc/laptop
+    ../../common/pc/laptop/ssd
+  ];
+
+  # Fix TRRS headphones missing a mic
+  # https://community.frame.work/t/headset-microphone-on-linux/12387/3
+  #
+  # This is temporary until a kernel patch is submitted
+  boot.extraModprobeConfig = ''
+    options snd-hda-intel model=dell-headset-multi
+  '';
+
+  # For fingerprint support
+  services.fprintd.enable = lib.mkDefault true;
+
+  # Custom udev rules
+  services.udev.extraRules = ''
+    # Ethernet expansion card support
+    ACTION=="add", SUBSYSTEM=="usb", ATTR{idVendor}=="0bda", ATTR{idProduct}=="8156", ATTR{power/autosuspend}="20"
+  '';
+
+  # Fix font sizes in X
+  # services.xserver.dpi = 200;
+
+  # Needed for desktop environments to detect/manage display brightness
+  hardware.sensor.iio.enable = lib.mkDefault true;
+}

framework/13-inch/common/intel.nix

@@ -0,0 +1,35 @@
+{ lib, pkgs, ... }: {
+  imports = [
+    ../../common/cpu/intel
+  ];
+
+  boot.kernelParams = [
+    # Fixes a regression in s2idle, making it more power efficient than deep sleep
+    "acpi_osi=\"!Windows 2020\""
+    # For Power consumption
+    # https://community.frame.work/t/linux-battery-life-tuning/6665/156
+    "nvme.noacpi=1"
+  ];
+
+  # Requires at least 5.16 for working wi-fi and bluetooth.
+  # https://community.frame.work/t/using-the-ax210-with-linux-on-the-framework-laptop/1844/89
+  boot.kernelPackages = lib.mkIf (lib.versionOlder pkgs.linux.version "5.16") (lib.mkDefault pkgs.linuxPackages_latest);
+
+  # Custom udev rules
+  services.udev.extraRules = ''
+    # Fix headphone noise when on powersave
+    # https://community.frame.work/t/headphone-jack-intermittent-noise/5246/55
+    SUBSYSTEM=="pci", ATTR{vendor}=="0x8086", ATTR{device}=="0xa0e0", ATTR{power/control}="on"
+  '';
+
+  # Mis-detected by nixos-generate-config
+  # https://github.com/NixOS/nixpkgs/issues/171093
+  # https://wiki.archlinux.org/title/Framework_Laptop#Changing_the_brightness_of_the_monitor_does_not_work
+  hardware.acpilight.enable = lib.mkDefault true;
+
+  # This adds a patched ectool, to interact with the Embedded Controller
+  # Can be used to interact with leds from userspace, etc.
+  # Not part of a nixos release yet, so package only gets added if it exists.
+  environment.systemPackages = lib.optional (pkgs ? "fw-ectool") pkgs.fw-ectool;
+
+}